Wi-Fi:Wi-Fi წვდომის წერტილის რეჟიში გამართვა

WiKi MikroTik geo გვერდიდან
Jump to navigation Jump to search

შესავალი

ჩვენ განვიხილავთ მაგალითს, როდესაც უკაბელო ქსელები კონფიგურირებულია ცალკე მარშრუტიზატორზე (წვდომის წერტილის როლი), რომელზეც იქნება მხოლოდ უსადენო ქსელები დაკონფიგურირებული და ის იქნება დაკავშირებული ძირითად მარშრუტიზატორზე რომელზეც უკვე გამართულია ლოკალური ქსელი და ის ემსახურება როგორც კარიბჭე ინტერნეტ ქსელში. კონსოლის მეშვეობით ნაჩვენებია საკონფიგურაციო ფაილი ნოლიდან. Wi-Fi ქსელის პარამეტრები შეესაბამება წინა მაგალითებზე განხილულ პარამეტრებს და წარმოადგენს განმეორებას ამ კონფიგურაციისათვის.

პარამეტრების ძირითადი მახასიათებლები:

  1. არ არის გარე (WAN) ინტერფეისი
  2. სტუმრის ქსელისთვის იქმნება მასკარადის(masquerade) წესი (განყოფილებაში Firewall-NAT) იმისათვის რომ ამ ქსელის მომხმარებლებმა შეძლონ ინტრენეტ ქსელში გასვლა დაშვების წერტილის მისამართიდან ძირითად ლოკალურ ქსელში, რადგან პირადი IP მისამართები არ მარშრუტიზირდება (#სქრინშოტი 5).

გრაფიკული ინტერფეისიდან

Wi-Fi დაშვების წერტილის კონფიგურაცია MikroTik მოწყობილობებზე - სქრინშოტი 1
Wi-Fi დაშვების წერტილის კონფიგურაცია MikroTik მოწყობილობებზე - სქრინშოტი 2
Wi-Fi დაშვების წერტილის კონფიგურაცია MikroTik მოწყობილობებზე - სქრინშოტი 3
Wi-Fi დაშვების წერტილის კონფიგურაცია MikroTik მოწყობილობებზე - სქრინშოტი 4
Wi-Fi დაშვების წერტილის კონფიგურაცია MikroTik მოწყობილობებზე - სქრინშოტი 5

კონსოლიდან

/interface bridge
add mtu=1500 name=bridge-local
/interface ethernet
set [ find default-name=ether1 ] name=ether1-LAN1-master
set [ find default-name=ether2 ] master-port=ether1-LAN1-master name=\
    ether2-LAN1
set [ find default-name=ether3 ] master-port=ether1-LAN1-master name=\
    ether3-LAN1
set [ find default-name=ether4 ] master-port=ether1-LAN1-master name=\
    ether4-LAN1
set [ find default-name=ether5 ] master-port=ether1-LAN1-master name=\
    ether5-LAN1
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
add authentication-types=wpa2-psk eap-methods="" mode=dynamic-keys name=\
    profile_local_wi-fi supplicant-identity="" wpa2-pre-shared-key=\
    Pass66word!
add authentication-types=wpa2-psk eap-methods="" mode=dynamic-keys name=\
    profile_guest_wi-fi supplicant-identity="" wpa2-pre-shared-key=Pass55word!
/interface wireless
set [ find default-name=wlan1 ] adaptive-noise-immunity=ap-and-client-mode \
    band=2ghz-b/g/n channel-width=20/40mhz-Ce country=russia disabled=\
    no distance=indoors frequency=auto frequency-mode=regulatory-domain \
    hw-protection-mode=rts-cts mode=ap-bridge noise-floor-threshold=-100 \
    security-profile=profile_local_wi-fi ssid=Main wireless-protocol=\
    802.11 wmm-support=enabled wps-mode=disabled
add disabled=no mac-address=00:00:00:00:00:00 master-interface=\
    wlan1 name="Guest Wi-Fi" security-profile=profile_guest_wi-fi ssid=\
    Guest wds-cost-range=0 wds-default-cost=0 wmm-support=enabled wps-mode=disabled
/ip pool
add name=dhcp_pool_local ranges=172.16.18.101-172.16.18.150
add name=dhcp_pool_guest ranges=10.11.12.101-10.11.12.150
/ip dhcp-server
add address-pool=dhcp_pool_guest disabled=no interface="Guest Wi-Fi" \
    lease-time=12h name=dhcp_guest
/interface bridge port
add bridge=bridge-local interface=ether1-LAN1-master
add bridge=bridge-local interface=wlan1
/ip address
add address=172.16.18.5/24 interface=bridge-local network=172.16.18.0
add address=10.11.12.1/24 interface="Guest Wi-Fi" network=10.11.12.0
/ip dhcp-server network
add address=10.11.12.0/24 dns-server=8.8.8.8,8.8.4.4 gateway=10.11.12.1
/ip dns
set allow-remote-requests=yes servers=8.8.8.8,8.8.4.4
/ip firewall filter
add chain=forward comment="Deny guest reguests" dst-address=172.16.18.0/24 src-address=10.11.12.0/24 connection-state=new action=drop 
add chain=forward comment="Deny guest reguests" dst-address=10.11.12.0/24 src-address=172.16.18.0/24 connection-state=new action=drop 
/ip firewall nat
add action=masquerade chain=srcnat out-interface=bridge-local src-address=\
    10.11.12.0/24
/ip route
add distance=1 gateway=172.16.18.1
/system identity
set name="AIR1"

შემოწმება

SSID Main დაკავშირებისას თქვენ უნდა გქონდეთ წვდომა ინტერნეტთან და ლოკალურ ქსელთან. SSID Guest ქსელთან დაკავშირებისას მხოლოდ ინტერნეტი უნდა იყოს ხელმისაწვდომი.